IBrowserPool Interface coclass BrowserPool | Multi-browser pool pattern | All methods take browserIndex As Long

Getting Started — Reg-Free Setup

Before you can use IBrowserPool, add this standard module to your project. It declares the Win32 API calls needed to load the OCX without COM registration, then exposes a GetPool() singleton you can call from any form.

Place the OCX in the same folder as your .accdb or .xlsm.

modLV2Pool.bas — add once per project

Option Explicit

' --- Win32 + OCX declarations (64-bit / 32-bit) ---
#If Win64 Then
    Private Declare PtrSafe Function SetDllDirectory Lib "kernel32" _
        Alias "SetDllDirectoryW" (ByVal lpPathName As LongPtr) As Long
    Private Declare PtrSafe Function LiteView2_ActivateManifest _
        Lib "LiteView2_x64.ocx" (ByVal path As LongPtr) As Long
    Private Declare PtrSafe Function LiteView2_CreateBrowserPool _
        Lib "LiteView2_x64.ocx" () As Object
#Else
    Private Declare PtrSafe Function SetDllDirectory Lib "kernel32" _
        Alias "SetDllDirectoryW" (ByVal lpPathName As LongPtr) As Long
    Private Declare PtrSafe Function LiteView2_ActivateManifest _
        Lib "LiteView2_x86.ocx" (ByVal path As LongPtr) As Long
    Private Declare PtrSafe Function LiteView2_CreateBrowserPool _
        Lib "LiteView2_x86.ocx" () As Object
#End If

Private m_Pool As Object

Public Function GetPool() As Object
    If m_Pool Is Nothing Then
        Dim p As String
        p = CurrentProject.Path          ' Access  (Excel: ThisWorkbook.Path)
        SetDllDirectory StrPtr(p)        ' Tell Windows where the OCX lives
        #If Win64 Then
            LiteView2_ActivateManifest StrPtr(p & "\LiteView2_x64.ocx")
        #Else
            LiteView2_ActivateManifest StrPtr(p & "\LiteView2_x86.ocx")
        #End If
        Set m_Pool = LiteView2_CreateBrowserPool()
        m_Pool.ActivateLicense "Your Company", "YOUR-LICENSE-KEY"  ' omit this line during 30-day trial
    End If
    Set GetPool = m_Pool
End Function

Usage from any form

Dim pool As Object
Set pool = GetPool()

' Create a browser and embed it in a Frame control
Dim idx As Long
idx = pool.CreateInControl("about:blank", Me.Frame1)

' Map a local folder to the virtual hostname https://lv2.local/
pool.SetLocalContentRoot idx, CurrentProject.Path & "\html"

' Navigate to a local HTML file
pool.Navigate idx, "https://lv2.local/dashboard.html"

Licensing

ActivateLicense is called once per process, before creating any browser instances. The recommended place is inside GetPool(), right after LiteView2_CreateBrowserPool():

m_Pool.ActivateLicense "Your Company", "YOUR-LICENSE-KEY"

Reg-Free (IBrowserPool)

' Inside GetPool(), right after LiteView2_CreateBrowserPool()
m_Pool.ActivateLicense "My Company", "LICENSE-KEY-HERE"

Registered (Design-Time Control)

' In your Form_Load or WebViewReady event
m_lv.ActivateLicense "My Company", "LICENSE-KEY-HERE"

License Status Properties

' Works on both pool and control objects
Debug.Print "Status: " & obj.LicenseStatus
Debug.Print "Type: "   & obj.LicenseType
Debug.Print "State: "  & obj.LicenseState       ' 0=Valid, 1=Trial, 2=Expired, 3=Invalid
Debug.Print "Days: "   & obj.TrialDaysRemaining

Key Difference

Every ILiteView2Ctrl method gains a browserIndex As Long first parameter on IBrowserPool:

' ILiteView2Ctrl (design-time OCX — single browser)
m_lv.Navigate "https://example.com"
m_lv.PushRecordset rs, "onData"

' IBrowserPool (multi-browser pool — add browserIndex)
pool.Navigate browserIndex, "https://example.com"
pool.PushRecordset browserIndex, rs, "onData"

Shared Methods Reference

All other ILiteView2Ctrl methods are available on IBrowserPool with browserIndex as the first parameter. See the ILiteView2Ctrl reference for full documentation.